// Class Main.as
package  
{
	import flare.basic.*
	import flare.core.*
	import flare.materials.*
	import flash.display.*
	import flash.display.*
	import flash.events.*
	
	public class Main extends Sprite
	{
		private var scene:Scene3D
		private var texture:Texture3D
		
		public function Main() 
		{
			stage.quality = "medium"
			
			// create the scene.
			scene = new Viewer3D( this )
			
			// load external texture.
			texture = scene.addTextureFromFile( "flare.jpg" )
			
			// define complete event.
			scene.addEventListener( Scene3D.COMPLETE_EVENT, completeEvent )			
		}
		
		private function completeEvent(e:Event):void 
		{
			// create the container mesh for sprites.
			var mesh:Mesh3D = new Mesh3D( "sprites container" )
			
			// create the sprite material.
			var material:SpriteTextureMaterial = new SpriteTextureMaterial( "flares", texture, BlendMode.SCREEN )
			
			// create the sprites.
			for ( var i:int = 0; i < 250; i++ )
			{
				var randomX:Number = Math.random() * 100 - 50
				var randomY:Number = Math.random() * 100 - 50
				var randomZ:Number = Math.random() * 100 - 50
				
				// we need a vertex to attach the sprite.
				var vertex:Vertex3D = new Vertex3D( randomX, randomY, randomZ )
				
				// create the sprite.
				var sprite:Sprite3D = new Sprite3D( vertex, 10, 10, material )
				
				// add vertex & poly ( the sprite is a simple poly ) to mesh.
				mesh.addVertex( vertex )
				mesh.addPoly( sprite )
			}
			
			// add mesh to scene.
			scene.addChild( mesh )
			
			// align the camera.
			scene.camera.setPosition( 0, 0, -200 )
		}
	}
}